VBScript WebDriver

Prerequisites

In order to create and run the tests in there are a few things we need to download and install:

• Download Selenium RC
• Download and install Java which is required for running Selenium
• In order to run Selenium tests we need to run Selenium Server which is shipped with Selenium RC. Since it's a Java program we run it by typing (replacing # with the current server version) java -jar selenium-server-#.jar in a console window.

Installation

• Download the latest build from: Sourceforge
• Extract it to a directory of your choice

Compatibility

VBS WebDriver has been reported to run on the following operating systems / architectures. If you have VBS WebDriver running on something not listed here, please tell us!

Run the demo tests

VBScript WebDriver contains some web tests ready to run that you can use as "templates". You can run them just by moving to the project directory and calling:

runTest.bat

Go to Examples page for more examples.

List of implemented methods.

List of JsonWireProtocol implemented methods

Include

VBScript 5.6 does not provide a statement to include files. But the ExecuteGlobal statement can be used to include program code from a file. The function below shows how to do it.

Sub Include(ByVal strFile)
   Set objFs = CreateObject("Scripting.FileSystemObject")
   Set WshShell = CreateObject("WScript.Shell")
   strFile = WshShell.ExpandEnvironmentStrings(strFile)
   file = objFs.GetAbsolutePathName(strFile)
   Set objFile = objFs.OpenTextFile(strFile)
   strCode = objFile.ReadAll
   objFile.Close
   ExecuteGlobal(strCode)
End Sub

Include "WebDriver.vbs"

Integrating with unit testing tools

VBS WebDriver is not a general purpose testing framework (unit or otherwise) is only a simple driver for WebDriver (Selenium 2), but VBScript WebDriver can work and be able to integrate with unit testing tools like ScriptUnit, ASPUnit or VBslib

ScriptUnit integration

VBS Webdriver integrates nicely with ScriptUnit. This is a tester in the same vein as JUnit and NUnit, but for the ActiveX scripting languages. It is similar to COMUnit, but without requiring the tests to be embedded in the testing application. ScriptUnit loads tests dynamically, so you can focus on the tests rather than the framework.

Write test

Write your VBS WebDriver tests in functions named TestXxxxx. You do not need to write a main-line that calls the functions - ScriptUnit will do that for you, and will let you call individual functions if you want.

Test functions must not return values, and take no parameters. The name must start with the word "Test".

If you define function called "Setup", it will be called before every test function in the file.

If you define a function called "TearDown", it will be called after every test function in the file. It will be called even if the test function fails.

If an unexpected error occurs during Setup or Teardown, then the test as a whole will be marked as failed.

If you do not write any test functions in your script, then the mainline will be run, and if no unexpected errors occur, then the script will be marked as a successful test.

For example:

Sub Include(ByVal strFile)
   Set objFs = CreateObject("Scripting.FileSystemObject")
   Set WshShell = CreateObject("WScript.Shell")
   strFile = WshShell.ExpandEnvironmentStrings(strFile)
   file = objFs.GetAbsolutePathName(strFile)      
   Set objFile = objFs.OpenTextFile(File)
   strCode = objFile.ReadAll
   objFile.Close
   ExecuteGlobal(strCode)
End Sub

Include "WebDriver.vbs"

Dim Driver 
Dim sSUT : sSUT = "http://htejera.users.sourceforge.net/vbswebdriver/demo/"
Dim sBrowser : sBrowser = "internet explorer"

sub setup		
	Set Driver = New WebDriver
	Driver.connect "127.0.0.1","4444",sBrowser, ""
end sub

sub Teardown()
	Set Driver = Nothing	
end sub

Sub Test_completeForm1() 
	Assert.IsSomething Driver, "object Driver was not created" 
	Driver.NavigateTo sSUT
	
	'Are you currently working with a real estate agent?
	Dim radio : Set radio = Driver.findElementBy(Driver.xpath,"//*[@id='sf1']/div/fieldset/input[2]") 
	Assert.IsSomething radio, "object Element by xpath was not created" 
	radio.click
	Set radio = Nothing
	
	'When would you like to move?
	Dim combo1 : Set combo1 = Driver.findElementBy(Driver.xpath,"//*[@id='recordPurchaseTimeFrameID']/option[2]") 
	Assert.IsSomething combo1, "object Element by xpath was not created" 
	combo1.click
	Set combo1 = Nothing
	
	'Purchase price range
	Dim combo2 : Set combo2 = Driver.findElementBy(Driver.xpath,"//*[@id='recordPurchasePriceRangeID']/option[6]") 
	Assert.IsSomething combo2, "object Element by xpath was not created" 
	combo2.click
	Set combo2 = Nothing
	
	'State
	Dim combo3 : Set combo3 = Driver.findElementBy(Driver.xpath,"//*[@id='recordPurchaseState']/option[6]") 
	Assert.IsSomething combo3, "object Element by xpath was not created" 
	combo3.click
	Set combo3 = Nothing
	
	'Desired property type
	Dim city : Set city = Driver.findElementBy(Driver.xpath,"//*[@id='recordCityName']") 
	Assert.IsSomething city, "object Element by xpath was not created" 
	city.sendKeys "Montevideo"
	Set city = Nothing
	
	
	'Desired property type
	Dim combo4 : Set combo4 = Driver.findElementBy(Driver.xpath,"//*[@id='recordPurchasePropertyTypeID']/option[3]") 
	Assert.IsSomething combo4, "object Element by xpath was not created" 
	combo4.click
	Set combo4 = Nothing
	
	'Next
	Dim button : Set button = Driver.findElementBy(Driver.name,"formNext1") 
	Assert.IsSomething button, "object Element by name was not created" 
	button.click
	Set button = Nothing
	
	'Verification
	Dim input : Set input = Driver.findElementBy(Driver.name,"recordPropertyAddress1") 
	Assert.IsSomething input , "object Element by name was not created" 
	Set input = Nothing
End Sub	

Assert commands

The scripting language is primed with an Assert object that supports the following methods for checking the validity of your object. If a check fails, then the message is logged and the script is stopped and marked with an error (red ball).

When there are multiple variations grouped together (e.g. Equal/Equals/IsEqual) then they are synonyms with no difference except for syntax. Use the one which reads best for you.

set db = CreateObject("Database")
Assert.IsTrue db.Login("foo","bar"), "Login failed"

 v = LCase("Foo")
 Assert.IsEqual( "foo", v )

 v = UCase("Foo")
 Assert.IsNotEqual( "foo", v, "upper and lowercase are the same" )

set v = CreateObject("scripting.dictionary")
set v = nothing
Assert.IsNothing( v, "variable was not cleared" )

set v = CreateObject("scripting.dictionary")
Assert.IsSomething( v, "object was not created" )
set v = nothing
Assert.IsNothing( v, "variable was not cleared" )

Assert.ExpectError "division by 0"
x = 1 / 0
Assert.Trace "should not reach this point - should have got error by now"

dim x
x = 1 / 0
Assert.Error "should not reach this point - should have got error by now"

Run test

Open ScriptUnit.exe, drag files into the ScriptUnit window, or add whole directories of test files in one go and just click the RUN button to reload the file and re-run the tests. Tests are easy to run and re-run just click the button to load and run the current test again.

Also Test runs can be automated using the command-line. Results can be stored in an NUnit-compatible XML file. This means that tests can be easily integrated into an automated build system.

For example, to run all the tests in the Tests folder, plus the C:\test.vbs file, and log the results to results.xml can be done like this:

ScriptUnit.exe /Q Tests c:\test.vbs /log results.xml

Script Unit Command Line